Mit AppleScript Adressen abgreifen

Nicht von Zauberhand, sondern mit der Hilfe von Apples Automatisierungssprache lassen sich die Absender aus empfangenen Mails ins Adressbuch überführen.

Gelegentlich stellt sich die Aufgabe, die Absenderadressen einer grösseren Zahl von Mails zusammenzutragen. Gründe dafür gibt es verschiedene. Es könnte einfach darum gehen, die Adresssammlung zu vervollständigen. Häufig ist das Ziel auch der Versand eines Newsletters oder eines Info-Mails an eine grössere Gruppe von Empfängern. Normalerweise müssten die Adressen in Handarbeit oder mit einem Extra-Programm herbeigeschafft werden. Doch dank AppleScript geht es auch einfacher. Die Automatisierungssprache, die es auf den Macs schon seit Urzeiten gibt, erledigt die Aufgabe nämlich im Alleingang. Nötig ist der folgende Code, der im Skripteditor von Mac OS X einzugeben ist. Dann braucht es nur noch zweierlei: Erstens müssen Sie in AppleMail diejenigen Mails markieren, deren Adressen ins Adressbuch transferiert werden sollen. Zweitens klicken Sie auf die «Ausführen»-Schaltfläche. Das wars schon – im Prinzip. Weitere beachtenswerte Dinge stehen im Kommentar am Anfang des Scripts.

(*
Address Harvester Mac OS X
Script zum automatischen Importieren von E-Mail-Adressen ins Adressbuch
Das Script stammt von Matthias Schüssler, 10. April 2008
Es wird wie folgt verwendet:
- Starten Sie das Programm Skripteditor und fügen Sie den gesamten Code ein
- Markieren Sie die Mails in Apple Mail, deren Absender Sie dem Adressbuch hinzufügen wollen

- Führen Sie das AppleScript aus

Sie finden nun alle automatisch importierten Adressen in einer neuen Gruppe namens «Auto-Import».
Zu beachten ist:
- Da das AppleScript nicht automatisch zwischen Vor- und Nachname unterscheiden kann, wird der ganze Name bei Nachname eingetragen.
- Wir haben das Script mit Mac OS X 10.5 Leopard entwickelt und bislang nicht mit anderen Versionen des Betriebssystems getestet. Wir können keine Garantie dafür übernehmen, dass es auch auf früheren Versionen läuft.

*)

tell application "Mail"
  set selectedMessages to selection

  if (count of selectedMessages) is equal to 0 then
    display alert "Keine Mails ausgewählt" message "Sie müssen Mails auswählen, bevor Sie dieses Script benuten."

  else
    tell application "Address Book"
      if not (exists group "Auto-Import") then make new group with properties {name:"Auto-Import"}

    end tell
    repeat with theMesage in selectedMessages
      set theSender to extract name from sender of theMesage

      set theAddress to extract address from sender of theMesage
      tell application "Address Book"

        if not (exists person theSender) then
          set newAddress to make new person with properties {last name:theSender}

          tell newAddress
            make new email at end of emails with properties {label:"Work", value:theAddress}

          end tell
          add newAddress to group "Auto-Import"
        end if

      end tell
    end repeat
    tell application "Address Book"

      save addressbook
    end tell
  end if
end tell

Erstellt: 04.11.2008, 20:17 Uhr

147124108642216 177194474660 de_DE 24340295

tr_fbConnectError

Tweet

352

Artikel als E-Mail versenden

Empfänger (E-Mail)*

Absender (E-mail)*

Ihre E-Mail wurde abgeschickt.

0